Internet Explorer 7 Beta 2をインストールせずに起動する方法

Google Operating System: Test Internet Explorer 7 Without Installing Itより。

この方法を使えば、自己責任ではありますが、既存のIE6はそのままにIE7β2を使うことができます。自分のサイトをIE6とIE7β2で見比べることができるようになるというわけ。やり方は以下の通り。
1.Internet Explorer 7 Beta 2を入手
まずはIE7β2をダウンロードする。

Internet Explorer 7: downloads
http://www.microsoft.com/windows/ie/downloads/default.mspx

2.中身を取り出す
WinRARかExplzh、あるいはCAB形式圧縮ファイルを解凍できるソフトを利用してダウンロードした「IE7BETA2-WindowsXP-x86-enu.exe」を解凍して中身を全部取り出す。

3.フォルダ移動
「Program Files」フォルダの中に「Internet Explorer 7」フォルダを作って、その中に解凍したファイルを全部移動させる

4.バッチファイルの作成
「Internet Explorer 7」フォルダの中に「ie7.bat」ファイルを作る。中身は以下のようにする。

@ECHO OFF
TITLE IE7 Launcher 1.4

ECHO IE7 STANDALONE LAUNCHER 1.4
ECHO Updated for IE7 Beta 2 Preview
ECHO.
ECHO Do not close this window or it will not clean up after itself properly.
ECHO You can pass a URL into this batch file, like this:
ECHO ie7.bat www.microsoft.com
ECHO.
ECHO More info here: http://weblogs.asp.net/jgalloway/archive/2005/12/28/434132.aspx
ECHO.
ECHO When you close IE7, this will remove the registry key and shut itself down.
ECHO.
ECHO Setting up IE7 for standalone mode...
PUSHD %~dp0

ECHO Removing IE7 registry key and set the version vector to "7.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}]
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\Interface\{000214E5-0000-0000-C000-000000000046}]
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="7.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg

REN SHLWAPI.DLL SHLWAPI.DLL.BAK
TYPE NUL > IEXPLORE.exe.local
ECHO Running IE7...
iexplore.exe "%1"

:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
:: Delete the temporary REG file
DEL %TEMP%.\IE7Fix.reg

ECHO Removing IE7 standalone files...
REN SHLWAPI.DLL.BAK SHLWAPI.DLL
DEL IEXPLORE.exe.local

:: Set the old version vector "6.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="6.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
REGEDIT /S %TEMP%.\IE7Fix.reg
DEL %TEMP%.\IE7Fix.reg

POPD
ECHO Complete, closing...

5.起動用VBSファイルの作成
「Internet Explorer 7」フォルダの中に「ie7.vbs」ファイルを作る。中身は以下のようにする。

Set oShell = CreateObject("WScript.Shell")
oShell.Run "ie7.bat", 0, True

6.起動確認
最後に「ie7.vbs」ファイルをクリックして起動する、これで終了。

ただし制限事項として、IE7β2のタブ機能は使えません…。また、IE6のアドレスバーに入力したアドレスがことごとく新しいウインドウで開いたりします…。まぁあくまでも見え方の確認程度ということです。

なお、もうこのIE7β2を使わない場合は「ie7fix.reg」をいうファイルを作成し、中身を以下のようにします。

Windows Registry Editor Version 5.00

[-HKEY_CLASSES_ROOT\CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}]

あとは「ie7fix.reg」をクリックすればOK、元に戻ります。